[SOLVED] CS #include threads/switch.h

#include threads/switch.h

#### struct thread *switch_threads (struct thread *cur, struct thread *next);
####
#### Switches from CUR, which must be the running thread, to NEXT,
#### which must also be running switch_threads(), returning CUR in
#### NEXTs context.
####
#### This function works by assuming that the thread were switching
#### into is also running switch_threads().Thus, all it has to do is
#### preserve a few registers on the stack, then switch stacks and
#### restore the registers.As part of switching stacks we record the
#### current stack pointer in CURs thread structure.

.globl switch_threads
.func switch_threads
switch_threads:
# Save callers register state.
#
# Note that the SVR4 ABI allows us to destroy %eax, %ecx, %edx,
# but requires us to preserve %ebx, %ebp, %esi, %edi.See
# [SysV-ABI-386] pages 3-11 and 3-12 for details.
#
# This stack frame must match the one set up by thread_create()
# in size.
pushl %ebx
pushl %ebp
pushl %esi
pushl %edi

# Get offsetof (struct thread, stack).
.globl thread_stack_ofs
mov thread_stack_ofs, %edx

# Save current stack pointer to old threads stack, if any.
movl SWITCH_CUR(%esp), %eax
movl %esp, (%eax,%edx,1)

# Restore stack pointer from new threads stack.
movl SWITCH_NEXT(%esp), %ecx
movl (%ecx,%edx,1), %esp

# Restore callers register state.
popl %edi
popl %esi
popl %ebp
popl %ebx
ret
.endfunc

.globl switch_entry
.func switch_entry
switch_entry:
# Discard switch_threads() arguments.
addl $8, %esp

# Call thread_schedule_tail(prev).
pushl %eax
.globl thread_schedule_tail
call thread_schedule_tail
addl $4, %esp

# Start thread proper.
ret
.endfunc